<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"  layout="horizontal">
	
	<mx:Script>
		<![CDATA[
			import mx.collections.ICollectionView;
			import mx.core.UIComponent;
			import mx.managers.DragManager;
			import mx.events.DragEvent;
			
			public function onListDragEnter(event:DragEvent):void
			{
				event.preventDefault();
				DragManager.acceptDragDrop(event.target as UIComponent);
				list.showDropFeedback(event);
			}
			
			public function onListDragOver(event:DragEvent):void
			{
				event.preventDefault();
				list.showDropFeedback(event);
			}
			
			public function onListDragExit(event:DragEvent):void
			{
				event.preventDefault();
				list.hideDropFeedback(event);
			}
			
			public function onListDragDrop(event:DragEvent):void
			{
				event.preventDefault();
				list.hideDropFeedback(event);
				var index:int = list.calculateDropIndex(event);
				
				//support drag from tree and other listbase components
				var items:Array = new Array();
				
				if(event.dragSource.hasFormat("treeItems"))
					items = items.concat(event.dragSource.dataForFormat("treeItems") as Array);
				
				if(event.dragSource.hasFormat("items"))
					items = items.concat(event.dragSource.dataForFormat("items") as Array);
				
				for each(var item:Object in items)
				{
					var obj:Object = new Object()
					obj.label = item.label as String;
					(list.dataProvider as ArrayCollection).addItemAt(obj, index);
				}
				
			}
			
			public function onListDragComplete(event:DragEvent):void
			{
				event.preventDefault();
				
				if(event.action == DragManager.MOVE && list.dragMoveEnabled)
				{
					//remove moved elements
					var items:Array = event.dragSource.dataForFormat("items") as Array;
					var coll:ArrayCollection = list.dataProvider as ArrayCollection;
					for each(var item:Object in items)
					{
						if(coll.contains(item))
						{
							coll.removeItemAt(coll.getItemIndex(item));
						}
					}
					
				}
			}
			
			public function onTreeDragEnter(event:DragEvent):void
			{
				event.preventDefault();
				DragManager.acceptDragDrop(event.target as UIComponent);
				tree.showDropFeedback(event);
			}
			
			public function onTreeDragOver(event:DragEvent):void
			{
				event.preventDefault();
				tree.showDropFeedback(event);
			}
	
			public function onTreeDragExit(event:DragEvent):void
			{
				event.preventDefault();
				tree.hideDropFeedback(event);
			}	
			
			public function onTreeDragDrop(event:DragEvent):void
			{
				event.preventDefault();
				tree.hideDropFeedback(event);
				var index:int = tree.calculateDropIndex(event);
				
				var items:Array = new Array();
				
				//we are supporting items from lists and trees
				if(event.dragSource.hasFormat("treeItems"))
					items = items.concat(event.dragSource.dataForFormat("treeItems") as Array);
				
				if(event.dragSource.hasFormat("items"))
					items = items.concat(event.dragSource.dataForFormat("items") as Array);
				
				//by default we add elements to the top level, but we could 
				//calculate the position in the hierarchical structure using the datadescriptor
				if(index > (tree.dataProvider as ICollectionView).length)
					index = (tree.dataProvider as ICollectionView).length;
				
				
				for each(var item:Object in items)
				{
					var obj:Object = new Object()
					obj.label = item.label as String;
					(tree.dataProvider as ArrayCollection).addItemAt(obj, index);
				}
			}	
			
			
		]]>
	</mx:Script>
	
		
	<mx:ArrayCollection id="listDP">
		<mx:Object label="list item 1"/>
		<mx:Object label="list item 2"/>
		<mx:Object label="list item 3"/>
	</mx:ArrayCollection>
	
	
	<mx:ArrayCollection id="treeDP">
		<mx:Object label="tree item 1"/>
		<mx:Object label="tree item 2"/>
		<mx:Object label="tree item 3">
			<mx:children>
				<mx:ArrayCollection>
					<mx:Object label="child item 1"/>
					<mx:Object label="child item 2"/>
				</mx:ArrayCollection>
			</mx:children>
		</mx:Object>
		
	</mx:ArrayCollection>
	
	
	<mx:List 
		id="list" 
		width="50%" 
		dragEnabled="true" 
		dataProvider="{listDP}" 
		dragEnter="onListDragEnter(event)"
		dragOver="onListDragOver(event)"
		dragExit="onListDragExit(event)"
		dragDrop="onListDragDrop(event)"
		dragComplete="onListDragComplete(event)"
		labelField="label"
		dragMoveEnabled="true"
		 >
		
	</mx:List>
	
	
	<mx:Tree 
		id="tree" 
		width="50%" 
		dragEnabled="true" 
		dataProvider="{treeDP}" 
		dragEnter="onTreeDragEnter(event)"
		dragOver="onTreeDragOver(event)"
		dragExit="onTreeDragExit(event)"
		dragDrop="onTreeDragDrop(event)"
		labelField="label"
		 >
		
	</mx:Tree>
	
</mx:Application>